Bygg din egen Bluetooth-nyhetsticker

Placerad på 2017-11-13

Exempel på nyhetsticker

Tillbehör

Arduino Uno R3 - klon I lager Eller en Arduino Nano € 11,90 MAX7219 4x Dot matrix-modul I lager Detta är displayen, du behöver minst 1, 2 är ännu bättre! € 10,55 HC-06 Bluetooth-modul med adapter - klon I lager Det här är HC-06 Bluetooth-slaven, du behöver 1 € 8,75 5,6KΩ Metallfilmmotstånd 1/4W - 100 stycken Slut i lager Spänningsdelaren för Bluetooth-modulen € 1,50 10KΩ Metallfilmmotstånd 1/4W - 10 st Slut i lager Spänningsdelaren för Bluetooth-modulen € 1,80 Mean Well SGA12E09-P1J strömförsörjning - 9V 1,33A I lager För extra ström kan USB inte leverera tillräckligt € 15,40 DC-uttag inbyggt 5,5 mm x 2,1 mm - 5 st Slut i lager € 2,55 Total € 52,45

Schemat:

Schemat visar hur allt ska kopplas ihop. Om du redan får en snurrande känsla av alla de där trådarna, titta inte för mycket på helheten, utan försök överväga och koppla ihop modulerna en efter en. Du kommer att se att det inte är så illa.

Schemat visar endast en LED-modul med fyrdubbla punktmatriser, i verkligheten kan du länka två tillsammans för en dubbel bredd!

Anslutningsschema för anslagstavla

Bluetooth-modulen kräver lite extra uppmärksamhet. Bluetooth-kommunikationssignalerna (TX och RX) fungerar på 3,3 volt, medan Arduino arbetar med 5 volt. De två motstånden kommer att reducera 5 volt från Arduino till cirka 3,3 volt.

Näringen:
Du kan se att en 5 volt strömkälla används. Du måste. En Arduino ansluten till USB kan inte leverera tillräckligt med ström för att driva LED-matrisen, speciellt med en dubbel matris.

Arduino bibliotek och skiss:

Arduino skissen använder två externa bibliotek, för att installera dessa, sök efter MD_MAX72xx i bibliotekshanteraren. Installera sedan MD_Max72xx och MD_Parola

Ticker USB Arduino bibliotek

Ställ in rätt modul:
Efter att ha installerat biblioteken måste vi berätta för MD_Max72xx-biblioteket vilken ledmatrismodul vi använder.

Leta upp filen på din hårddisk: MD_MAX72xx.h
(förmodligen i mappen C:\Users\ditt namn\Documents\ Arduino \libraries\MD_MAX72XX\src\)

//Op regel 214, zie je staan:   
#define   USE_PAROLA_HW   1, verander die 1 in 0

//Op regel 237 zie je staan: 
#define   USE_FC16_HW   0,   verander die 0 in 1.

Arduino skissen:

Då kan vi nu ladda skissen.
Kopiera skissen och klistra in koden i Arduino -mjukvaran, välj rätt com-port och skriv Arduino och tryck på ladda upp!

#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>
#include <SoftwareSerial.h>
#include <EEPROM.h>
#define MAX_DEVICES 8
#define CLK_PIN   13
#define DATA_PIN  11
#define CS_PIN    10

// Use softserial for the bluetooth module
SoftwareSerial mySerial(2, 3);

// HARDWARE SPI
MD_Parola LK = MD_Parola(CS_PIN, MAX_DEVICES);

uint8_t scrollSpeed = 30;    // default frame delay value
textEffect_t scrollEffect = PA_SCROLL_LEFT;
textPosition_t scrollAlign = PA_LEFT;
uint16_t scrollPause = 2000; // in milliseconds

// Global message buffers shared by Serial and Scrolling functions
#define  BUF_SIZE  75
char curMessage[BUF_SIZE];
char newMessage[BUF_SIZE];
bool newMessageAvailable = false;

void setup()
{
  // Enable the next line to clear the message from eeprom.
  // EEPROM.write(0,1);
  
  mySerial.begin(9600); 
  delay(500);
  
  // The next line configures the BT-04 (BT-06) Module to NOT report connection status. 
  mySerial.write("\r\nAT+ENABLEIND0\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  // change the name of the BT-04 (BT-06) device, this will not work for HC-06
  mySerial.write("AT+NAMELichtkrant01\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  LK.begin();
  LK.displayClear();
  LK.displaySuspend(false);
  LK.displayText(curMessage, scrollAlign, scrollSpeed, scrollPause, scrollEffect, scrollEffect);  

  // Get the last message from EEPROM
  getMessageFromEeprom();
}


void loop()
{  
  readSerial();
  if (LK.displayAnimate())
  {
    if (newMessageAvailable)
    {
      strcpy(curMessage, newMessage);
      newMessageAvailable = false;
      storeMessageInEeprom();
    }
    LK.displayReset();
  }
}


  
void readSerial(void) {
  static char *cp = newMessage;
  while (mySerial.available())  
  {
    *cp = (char)mySerial.read();
    if ( (*cp == '\r') || (*cp == '\n') || (cp - newMessage >= BUF_SIZE-2)) // end of message character or full buffer
    {
      *cp = '\0'; // end the string   
      cp = newMessage;
      newMessageAvailable = true;
      mySerial.print("Nieuwe Boodschap = ");
      mySerial.println(newMessage);
      ClearRXbuffer();
    }
    else  // move char pointer to next position
      cp++;
  }
}


void storeMessageInEeprom(){
  // Store the message in EEPROM
  EEPROM.write(0,251);
  int i=0;
  char c=curMessage[i];
  while (c !=0){
    EEPROM.write(i+1,c);
    i++;
    c=curMessage[i];
    }
    EEPROM.write(i+1,0);
}

void getMessageFromEeprom(){
  if (EEPROM.read(0)!=251){
    strcpy(curMessage, "Hello! Please Send new message over bluetooth");
    newMessage[0] = '\0';
    } else {      
      int i=0;
      char c = EEPROM.read(i+1);
      while (c!=0){
        curMessage[i++]=c;
        c = EEPROM.read(i+1);
        }
        curMessage[i] = '\0';
        newMessageAvailable=false;         
    }
}

void ClearRXbuffer(){
  while (mySerial.available()){
    char c=mySerial.read(); 
    delay(5);
    } 
}

Om allt är bra (och varför inte?) kommer du nu att se meddelandet "Hej, skicka ett nytt meddelande via bluetooth". Så det är hög tid att installera Android-appen på din telefon och skicka ett nytt meddelande via Bluetooth!

Android-appen:

För att ändra texten på nyhetstickern behöver vi ett Bluetooth-terminalprogram, till exempel Serial Bluetooth Terminal från Kai Morich, via AppStore.

SeriellBluetoothTerminal

Appens funktion är ganska självförklarande, men i videon visar jag det steg för steg.

bluetooth terminal

Observera: Apples iOS kan inte ansluta till den använda bluetooth-modulen, så detta fungerar bara med Android-enheter.

titta på videon

Finns det fortfarande oklarheter? Du kan ta en närmare titt på allt i den här videon.

Postat av Bart Venneker Hemsida | Youtube Bart Venneker är elektronikhobbyist och gör utbildningsfilmer om elektronik, Arduino och 3d-skrivare.

Kommentarer

Ad Laat

Tyvärr kan justeringarna i biblioteket inte hittas, vilket gör att tickern inte fungerar, synd! Kan en annan version ha använts? Hälsningar, Ad de Laat

Placerad på 19 november 2023

