Arduino Leonardo - elektroniskt lås

Placerad på 2020-06-22

Hämta koden från användarinmatning

Så som jag beskrev i del 1 måste vi få all nödvändig input från användaren och kontrollera koden med den sparade.

Och kontrollera även om displayen inte svämmar över. Det hanteras av denna kod.

GetCode function

const unsigned char MaxPasscodeLength = 19;
unsigned char PasscodeLength;
char Data[MaxPasscodeLength];
char Master[MaxPasscodeLength];

unsigned char data_count = 0;
char Key;

void GetCode() {							// This piece of code handles getting the code from the user
   if (data_count < MaxPasscodeLength) {
    Data[data_count] = Key; 
    lcd.setCursor(data_count,1); 
    lcd.print("*");
    if (EnableDebug) {
      Serial.println();
      Serial.print("Data_count: ");
      Serial.println(data_count);
      Serial.print("Data: ");
      Serial.println(Data[data_count]);
    }
    data_count++;
   }
   else {
      lcd.setCursor(data_count,1);
      lcd.print("*");
      lcd.setCursor(0, 3);
      lcd.print("Passcode Overflow");
      if (EnableDebug) {
        Serial.println();
        Serial.println("Passcode Overflow Error");
      }
      _delay_ms(1000);
      lcd.clear();
      clearData();
   }
}

Kontrollerar koden

Vi måste också kontrollera om koden matchar den sparade koden, så vi vet när vi kan öppna låset och när vi inte gör det.

CheckCode Function

void CodeCorrect() {
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Correct");
  LockState = true;
  _delay_ms(1000);
  if (EnableDebug) {
    Serial.println();
    Serial.println("Opened");
  }
}

void CodeIncorrect() {
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Incorrect");
  if (EnableDebug) {
    Serial.println();
    Serial.println("Incorrect PSWD");
  }
  LockState = false;
  _delay_ms(1000);
}

void OpenLock() {
  if (EnableServo) {
    Lock.write(90);
  }
  lcd.setCursor(0,0);
  lcd.print("Lock Opened");
  lcd.setCursor(0,2);
  lcd.print("Press -* to lock");
  if (EnablePasscodeChange) {
    lcd.setCursor(3,3);
    lcd.print("-# to change code");
  }
  TimeLastActivity = millis();
}

void CloseLock() {
  if (EnableServo) {
    Lock.write(180);
  }
  LockState = false;
  lcd.clear();
  if (EnableDebug) {
    Serial.println();
    Serial.println("Closing");
  }
  TimeLastActivity = millis();
}

void CheckCode() {
  if(data_count == PasscodeLength){
      Data[PasscodeLength] = 0;
      _delay_ms(500);
      lcd.clear();
      if (EnableDebug) {
        Serial.println();
        Serial.print("Data:   ");
        Serial.println(Data);
        Serial.print("Master: ");
        Serial.println(Master);
      }
      if(!strcmp(Data, Master)){
          CodeCorrect();
        }

      else{
          if (EnableDebug) {
            Serial.println();
            Serial.print("PasscodeLength: ");
            Serial.println(PasscodeLength);
            Serial.print("DataCount: ");
            Serial.println(data_count);
          }
          CodeIncorrect();
        }
  }
  else {
      if (EnableDebug) {
        Serial.println();
        Serial.print("Data:   ");
        Serial.println(Data);
        Serial.print("Master: ");
        Serial.println(Master);
        Serial.println();
        Serial.print("PasscodeLength: ");
        Serial.println(PasscodeLength);
        Serial.print("DataCount: ");
        Serial.println(data_count);
      }
      CodeIncorrect();
    }
  lcd.clear();
  clearData();
}

Föregående sida 7. Koden - del 2 - LCD-skärmen Nuvarande sida 8. Koden - del 3 - Koden Nästa sida 9. Koden - del 4 - Fler koder 1. Introduktion 2. Schemat 3. Knappsatsen 4. LCD-modulen 5. Servon 6. Koden - del 1 - Knappsatsen 7. Koden - del 2 - LCD-skärmen 8. Koden - del 3 - Koden 9. Koden - del 4 - Fler koder 10. Koden - del 5 - Setup and Loop 11. Hela koden Postat av Sander Speetjens

Arduino Leonardo - elektroniskt lås

Hämta koden från användarinmatning

GetCode function

Kontrollerar koden

CheckCode Function

Kommentarer